Galois Groups of Number Fields¶

AUTHORS:

William Stein (2004, 2005): initial version
David Loeffler (2009): rewrite to give explicit homomorphism groups

TESTS:

Standard test of pickleability:

sage: G = NumberField(x^3 + 2, 'alpha').galois_group(type="pari"); G
Galois group PARI group [6, -1, 2, "S3"] of degree 3 of the Number Field in alpha with defining polynomial x^3 + 2
sage: G == loads(dumps(G))
True

sage: G = NumberField(x^3 + 2, 'alpha').galois_group(names='beta'); G
Galois group of Galois closure in beta of Number Field in alpha with defining polynomial x^3 + 2
sage: G == loads(dumps(G))
True

sage.rings.number_field.galois_group.GaloisGroup¶: alias of GaloisGroup_v1

class sage.rings.number_field.galois_group.GaloisGroupElement¶

Bases: sage.groups.perm_gps.permgroup_element.PermutationGroupElement

An element of a Galois group. This is stored as a permutation, but may also be made to act on elements of the field (generally returning elements of its Galois closure).

EXAMPLE:

sage: K.<w> = QuadraticField(-7); G = K.galois_group()
sage: G[1]
(1,2)
sage: G[1](w + 2)
-w + 2

sage: L.<v> = NumberField(x^3 - 2); G = L.galois_group(names='y')
sage: G[1]
(1,2)(3,4)(5,6)
sage: G[1](v)
1/84*y^4 + 13/42*y
sage: G[1]( G[1](v) )
-1/252*y^4 - 55/126*y

as_hom(*args, **kwds)¶

Return the homomorphism L -> L corresponding to self, where L is the Galois closure of the ambient number field.

EXAMPLE:

sage: G = QuadraticField(-7,'w').galois_group()
sage: G[1].as_hom()
Ring endomorphism of Number Field in w with defining polynomial x^2 + 7
Defn: w |--> -w

ramification_degree(P)¶

Return the greatest value of v such that s acts trivially modulo P^v. Should only be used if P is prime and s is in the decomposition group of P.

EXAMPLE:

sage: K.<b> = NumberField(x^3 - 3,'a').galois_closure()
sage: G=K.galois_group()
sage: P = K.primes_above(3)[0]
sage: s = hom(K, K, 1/54*b^4 + 1/18*b)
sage: G(s).ramification_degree(P)
4

class sage.rings.number_field.galois_group.GaloisGroup_subgroup(ambient, elts)¶

Bases: sage.rings.number_field.galois_group.GaloisGroup_v2

A subgroup of a Galois group, as returned by functions such as decomposition_group.

fixed_field()¶

Return the fixed field of this subgroup (as a subfield of the Galois closure of the number field associated to the ambient Galois group).

EXAMPLE:

sage: L.<a> = NumberField(x^4 + 1)
sage: G = L.galois_group()
sage: H = G.decomposition_group(L.primes_above(3)[0])
sage: H.fixed_field()
(Number Field in a0 with defining polynomial x^2 + 2, Ring morphism:
From: Number Field in a0 with defining polynomial x^2 + 2
To:   Number Field in a with defining polynomial x^4 + 1
Defn: a0 |--> a^3 + a)

class sage.rings.number_field.galois_group.GaloisGroup_v1(group, number_field)¶

Bases: sage.structure.sage_object.SageObject

A wrapper around a class representing an abstract transitive group.

This is just a fairly minimal object at present. To get the underlying group, do G.group(), and to get the corresponding number field do G.number_field(). For a more sophisticated interface use the type=None option.

EXAMPLES:

sage: K = QQ[2^(1/3)]
sage: G = K.galois_group(type="pari"); G
Galois group PARI group [6, -1, 2, "S3"] of degree 3 of the Number Field in a with defining polynomial x^3 - 2
sage: G.order()
6
sage: G.group()
PARI group [6, -1, 2, "S3"] of degree 3
sage: G.number_field()
Number Field in a with defining polynomial x^3 - 2

group()¶

Return the underlying abstract group.

EXAMPLES:

sage: G = NumberField(x^3 + 2*x + 2, 'theta').galois_group(type="pari")
sage: H = G.group(); H
PARI group [6, -1, 2, "S3"] of degree 3
sage: P = H.permutation_group(); P  # optional -- requires Gap optional databases
Transitive group number 2 of degree 3
sage: list(P)                       # optional 
[(), (2,3), (1,2), (1,2,3), (1,3,2), (1,3)]

number_field()¶

Return the number field of which this is the Galois group.

EXAMPLES:

sage: G = NumberField(x^6 + 2, 't').galois_group(type="pari"); G
Galois group PARI group [12, -1, 3, "D(6) = S(3)[x]2"] of degree 6 of the Number Field in t with defining polynomial x^6 + 2
sage: G.number_field()
Number Field in t with defining polynomial x^6 + 2

order()¶

Return the order of this Galois group.

EXAMPLES:

sage: G = NumberField(x^5 + 2, 'theta_1').galois_group(type="pari"); G
Galois group PARI group [20, -1, 3, "F(5) = 5:4"] of degree 5 of the Number Field in theta_1 with defining polynomial x^5 + 2
sage: G.order()
20

class sage.rings.number_field.galois_group.GaloisGroup_v2(number_field, names=None)¶

Bases: sage.groups.perm_gps.permgroup.PermutationGroup_generic

The Galois group of an (absolute) number field.

Note

We define the Galois group of a non-normal field K to be the Galois group of its Galois closure L, and elements are stored as permutations of the roots of the defining polynomial of L, not as permutations of the roots (in L) of the defining polynomial of K. The latter would probably be preferable, but is harder to implement. Thus the permutation group that is returned is always simply-transitive.

The ‘arithmetical’ features (decomposition and ramification groups, Artin symbols etc) are only available for Galois fields.

artin_symbol(P)¶

Return the Artin symbol $\left(\frac{K / \QQ}{\mathfrak{P}}\right)$ , where K is the number field of self, and $\mathfrak{P}$ is an unramified prime ideal. This is the unique element s of the decomposition group of $\mathfrak{P}$ such that $s(x) = x^p \bmod \mathfrak{P}$ , where p is the residue characteristic of $\mathfrak{P}$ .

EXAMPLES:

sage: K.<b> = NumberField(x^4 - 2*x^2 + 2, 'a').galois_closure()
sage: G = K.galois_group()
sage: [G.artin_symbol(P) for P in K.primes_above(7)]
[(1,4)(2,3)(5,8)(6,7), (1,4)(2,3)(5,8)(6,7), (1,5)(2,6)(3,7)(4,8), (1,5)(2,6)(3,7)(4,8)]
sage: G.artin_symbol(17)
...
ValueError: Fractional ideal (17) is not prime
sage: QuadraticField(-7,'c').galois_group().artin_symbol(13)
(1,2)
sage: G.artin_symbol(K.primes_above(2)[0])
...
ValueError: Fractional ideal (...) is ramified

complex_conjugation(P=None)¶

Return the unique element of self corresponding to complex conjugation, for a specified embedding P into the complex numbers. If P is not specified, use the “standard” embedding, whenever that is well-defined.

EXAMPLE:

sage: L = CyclotomicField(7)
sage: G = L.galois_group()
sage: G.complex_conjugation()
(1,6)(2,3)(4,5)

An example where the field is not CM, so complex conjugation really depends on the choice of embedding:

sage: L = NumberField(x^6 + 40*x^3 + 1372,'a')
sage: G = L.galois_group()
sage: [G.complex_conjugation(x) for x in L.places()]
[(1,3)(2,6)(4,5), (1,5)(2,4)(3,6), (1,2)(3,4)(5,6)]

decomposition_group(P)¶

Decomposition group of a prime ideal P, i.e. the subgroup of elements that map P to itself. This is the same as the Galois group of the extension of local fields obtained by completing at P.

This function will raise an error if P is not prime or the given number field is not Galois.

P can also be an infinite prime, i.e. an embedding into $\RR$ or $\CC$ .

EXAMPLE:

sage: K.<a> = NumberField(x^4 - 2*x^2 + 2,'b').galois_closure()
sage: P = K.ideal([17, a^2])
sage: G = K.galois_group()
sage: G.decomposition_group(P)
Subgroup [(), (1,8)(2,7)(3,6)(4,5)] of Galois group of Number Field in a with defining polynomial x^8 - 20*x^6 + 104*x^4 - 40*x^2 + 1156
sage: G.decomposition_group(P^2)
...
ValueError: Fractional ideal (...) is not prime
sage: G.decomposition_group(17)
...
ValueError: Fractional ideal (17) is not prime

An example with an infinite place:

sage: L.<b> = NumberField(x^3 - 2,'a').galois_closure(); G=L.galois_group()
sage: x = L.places()[0]
sage: G.decomposition_group(x).order()
2

inertia_group(P)¶

Return the inertia group of the prime P, i.e. the group of elements acting trivially modulo P. This is just the 0th ramification group of P.

EXAMPLE:

sage: K.<b> = NumberField(x^2 - 3,'a')
sage: G = K.galois_group()
sage: G.inertia_group(K.primes_above(2)[0])
Galois group of Number Field in b with defining polynomial x^2 - 3
sage: G.inertia_group(K.primes_above(5)[0])
Subgroup [()] of Galois group of Number Field in b with defining polynomial x^2 - 3

is_galois()¶

Return True if the underlying number field of self is actually Galois.

EXAMPLE:

sage: NumberField(x^3 - x + 1,'a').galois_group(names='b').is_galois()
False
sage: NumberField(x^2 - x + 1,'a').galois_group().is_galois()
True

list()¶

List of the elements of self.

EXAMPLE:

sage: NumberField(x^3 - 3*x + 1,'a').galois_group().list()
[(), (1,2,3), (1,3,2)]

ngens()¶

Number of generators of self.

EXAMPLE:

sage: QuadraticField(-23, 'a').galois_group().ngens()
1

number_field()¶

The ambient number field.

EXAMPLE:

sage: K = NumberField(x^3 - x + 1, 'a')
sage: K.galois_group(names='b').number_field() is K
True

ramification_breaks(P)¶

Return the set of ramification breaks of the prime ideal P, i.e. the set of indices i such that the ramification group $G_{i+1} \ne G_{i}$ . This is only defined for Galois fields.

EXAMPLE:

sage: K.<b> = NumberField(x^8 - 20*x^6 + 104*x^4 - 40*x^2 + 1156)
sage: G = K.galois_group()
sage: P = K.primes_above(2)[0]
sage: G.ramification_breaks(P)
{1, 3, 5}
sage: min( [ G.ramification_group(P, i).order() / G.ramification_group(P, i+1).order() for i in G.ramification_breaks(P)] )
2

ramification_group(P, v)¶

Return the vth ramification group of self for the prime P, i.e. the set of elements s of self such that s acts trivially modulo P^(v+1). This is only defined for Galois fields.

EXAMPLE:

sage: K.<b> = NumberField(x^3 - 3,'a').galois_closure()
sage: G=K.galois_group()
sage: P = K.primes_above(3)[0]
sage: G.ramification_group(P, 3)
Subgroup [(), (1,3,6)(2,4,5), (1,6,3)(2,5,4)] of Galois group of Number Field in b with defining polynomial x^6 + 60*x^3 + 3087
sage: G.ramification_group(P, 5)
Subgroup [()] of Galois group of Number Field in b with defining polynomial x^6 + 60*x^3 + 3087

splitting_field()¶

The Galois closure of the ambient number field.

EXAMPLE:

sage: K = NumberField(x^3 - x + 1, 'a')
sage: K.galois_group(names='b').splitting_field()
Number Field in b with defining polynomial x^6 - 14*x^4 - 20*x^3 + 49*x^2 + 140*x + 307
sage: L = QuadraticField(-23, 'c'); L.galois_group().splitting_field() is L
True

subgroup(elts)¶

Return the subgroup of self with the given elements. Mostly for internal use.

EXAMPLE:

sage: G = NumberField(x^3 - x - 1,'a').galois_closure('b').galois_group()
sage: G.subgroup([ G(1), G([(1,5,2),(3,4,6)]), G([(1,2,5),(3,6,4)])])
Subgroup [(), (1,5,2)(3,4,6), (1,2,5)(3,6,4)] of Galois group of Number Field in b with defining polynomial x^6 - 14*x^4 + 20*x^3 + 49*x^2 - 140*x + 307

Galois Groups of Number Fields¶

Previous topic

Next topic

This Page

Navigation

Galois Groups of Number Fields¶

Previous topic

Next topic

This Page

Quick search

Navigation